Освой Arduino играючи

Сайт Александра Климова

Шкодим

/* Моя кошка замечательно разбирается в программировании. Стоит мне объяснить проблему ей - и все становится ясно. */
John Robbins, Debugging Applications, Microsoft Press, 2000

Главная Примеры Библиотеки Playground Датчики Компоненты Shields ESP32 M5Stack Документация Статьи Электроника

ESP32: WiFiServer

Веб-сервер. Управляем цифровыми выводами
Веб-сервер. Снимаем показания с аналоговых выводов
Сокет-сервер. Общаемся через Putty

О подключении к WiFi-сети можно почитать в отдельной статье.

В состав библиотеки WiFi.h входит класс WiFiServer, который позволяет использовать плату в качестве сервера. Для инициализации нужно вызвать конструктор класса и указать номера порта, например, 80.

Веб-сервер. Управляем цифровыми выводами

SimpleWiFiServer

В составе примеров Examples/WiFi есть пример SimpleWiFiServer для создания веб-сервера, при помощи которого можно включать и выключать светодиод. В примере светодиод подключается к выводу 5. В скетче нужно указать имя и пароль вашей WiFi-сети. После запуска через монитор порта вы получите свой ip-адрес. Запускаете браузер в компьютере или телефоне и увидите страницу с двумя ссылками. Также можно управлять светодиодом чере адресную строку: http://yourAddress/H включает светодиод, а http://yourAddress/L выключает.

Создадим расширенный пример веб-сервера.

Плата ESP32 может работать как веб-сервер. Подключим к плате два светодиода к выводам 26 и 27 или выберите другие.

После загрузки скетча на плату мы узнаем её веб-адрес, к которому можем подключиться через браузер на домашнем компьютере или телефоне, используя локальную WiFi-сеть. По указанному адресу будет находиться страничка с двумя кнопками, с помощью которых можно включать или выключать светодиоды.


// Загружаем библиотеку Wi-Fi
#include <WiFi.h>

// Замените на свой идентификатор и пароль
const char* ssid = "your_ssid";
const char* password = "your_pass";

// Номер порта для сервера
WiFiServer server(80);

// HTTP-запрос
String header;

// текущее состояние кнопки
String output26State = "off";
String output27State = "off";

// Номера выводов
const int output26 = 26;
const int output27 = 27;

void setup() {
  Serial.begin(115200);
  // Настраиваем выводы платы
  pinMode(output26, OUTPUT);
  pinMode(output27, OUTPUT);
  // Переводим выводы в LOW
  digitalWrite(output26, LOW);
  digitalWrite(output27, LOW);

  // Подключаемся к Wi-Fi
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Выводим локальный IP-адрес и запускаем сервер
  Serial.println("");
  Serial.println("WiFi connected.");
  Serial.println("IP address: ");
  Serial.println(WiFi.localIP());
  server.begin();
}

void loop() {
  WiFiClient client = server.available(); // прослушка входящих клиентов
  if (client) { // Если подключается новый клиент,
    Serial.println("New Client."); // выводим сообщение
    String currentLine = "";
    while (client.connected()) { // цикл, пока есть соединение клиента
      if (client.available()) { // если от клиента поступают данные,
        char c = client.read(); // читаем байт, затем
        Serial.write(c); // выводим на экран
        header += c;
        if (c == '\n') { // если байт является переводом строки
          // если пустая строка, мы получили два символа перевода строки
          // значит это конец HTTP-запроса, формируем ответ сервера:
          if (currentLine.length() == 0) {
            // HTTP заголовки начинаются с кода ответа (напр., HTTP / 1.1 200 OK)
            // и content-type, затем пустая строка:
            client.println("HTTP/1.1 200 OK");
            client.println("Content-type:text/html");
            client.println("Connection: close");
            client.println();

            // Включаем или выключаем светодиоды
            if (header.indexOf("GET /26/on") >= 0) {
              Serial.println("GPIO 26 on");
              output26State = "on";
              digitalWrite(output26, HIGH);
            } else if (header.indexOf("GET /26/off") >= 0) {
              Serial.println("GPIO 26 off");
              output26State = "off";
              digitalWrite(output26, LOW);
            } else if (header.indexOf("GET /27/on") >= 0) {
              Serial.println("GPIO 27 on");
              output27State = "on";
              digitalWrite(output27, HIGH);
            } else if (header.indexOf("GET /27/off") >= 0) {
              Serial.println("GPIO 27 off");
              output27State = "off";
              digitalWrite(output27, LOW);
            }
            // Формируем веб-страницу на сервере
            client.println("<!DOCTYPE html><html>");
            client.println("<head><meta name=\"viewport\" content=\"width=device-width, initial-scale=1\">");
            client.println("<link rel=\"icon\" href=\"data:,\">");
            // CSS для кнопок
            // можете менять под свои нужды
            client.println("<style>html { font-family: Helvetica; display: inline-block; margin: 0px auto; text-align: center;}");
            client.println(".button { background-color: #4CAF50; border:  none; color: white; padding: 16px 40px;");
            client.println("text-decoration: none; font-size: 30px; margin: 2px; cursor: pointer;}");
            client.println(".button2 {background-color:#555555;}</style></head>");
            client.println("<body><h1>ESP32 Web Server</h1>");
            // Выводим текущее состояние кнопок
            client.println("<p>GPIO 26 - State " + output26State + "</p>");
            // Если output26State сейчас off, то выводим надпись ON
            if (output26State == "off") {
              client.println("<p><a href=\"/26/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/26/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            // Аналогично для второй кнопки
            client.println("<p>GPIO 27 - State " + output27State + "</p>");
            if (output27State == "off") {
              client.println("<p><a href=\"/27/on\"><button class=\"button\">ON</button></a></p>");
            } else {
              client.println("<p><a href=\"/27/off\"><button class=\"button button2\">OFF</button></a></p>");
            }
            client.println("</body></html>");
            // HTTP-ответ завершается пустой строкой
            client.println();
            break;
          } else { // если получили новую строку, очищаем currentLine
            currentLine = "";
          }
        } else if (c != '\r') { // Если получили что-то ещё кроме возврата строки,
          currentLine += c; // добавляем в конец currentLine
        }
      }
    }
    // Очистим переменную
    header = "";
    // Закрываем соединение
    client.stop();
    Serial.println("Client disconnected.");
    Serial.println("");
  }
}

Открываем Serial Monitor, узнаём адрес сервера, подключаемся к нему через компьютер или телефон. Откроется страница с кнопками, нажимаем и управляем светодиодами.

Web server

При работе с сервером смотрите на сообщения в Serial Monitor, в котором отображается информация о подключении новых клиентов.

При общении мы используем GET-запросы, поэтому при нажатии кнопок будет меняться адрес в браузере .../26/on.

Веб-сервер. Снимаем показания с аналоговых выводов

Также мы можем снимать показания с аналоговых выводов, в нашем примере это будут выводы 34, 36, 39.


// Загружаем библиотеку Wi-Fi
#include <WiFi.h>

// Замените на свой идентификатор и пароль точки доступа Wi-Fi
const char* ssid     = "your_ssid";
const char* password = "your_pass";

// Номер порта для сервера
WiFiServer server(80);

// заводим буфер и счётчик для буфера
char lineBuf[80];
int charCount = 0;

void setup() {
  Serial.begin(115200);
  // делаем паузу на открытие монитора порта
  delay(5000);
  
  // инициализируем аналоговые пины
  pinMode(34, INPUT);
  pinMode(36, INPUT);
  pinMode(39, INPUT);
  
  // Подключаемся к Wi-Fi
  Serial.println();
  Serial.print("Connecting to ");
  Serial.println(ssid);
  WiFi.begin(ssid, password);
  while (WiFi.status() != WL_CONNECTED) {
    delay(500);
    Serial.print(".");
  }
  // Выводим локальный IP-адрес и запускаем сервер
  Serial.println("");
  Serial.println("Wi-Fi connected");
  Serial.println("IP-address: ");
  Serial.println(WiFi.localIP());
  // запускаем сервер
  server.begin();
}

void loop() {
  WiFiClient client = server.available(); // прослушка входящих клиентов
  if (client) {
    Serial.println("New client");
    memset(lineBuf, 0, sizeof(lineBuf));
    charCount = 0;
    // HTTP-запрос заканчивается пустой строкой
    boolean currentLineIsBlank = true;
    while (client.connected()) {
      client.println("HTTP/1.1 200 OK");
      client.println("Content-Type: text/html");
      client.println("Connection: close");
      client.println();
	  
      // формируем веб-страницу
      String webPage = "<!DOCTYPE HTML>";
      webPage += "<html>";
      webPage += "<head>";
      webPage += "<meta name=\"viewport\" content=\"width=device-width,";
      webPage += "initial-scale=1\">";
      webPage += "</head>";
      webPage += "<body>";
      webPage += "<h1>ESP32 - Web Server</h1>";
      webPage += "<p>AnalogPin 34 = ";
      webPage +=    analogRead(34);
      webPage += "</p>";
      webPage += "<p>AnalogPin 36 = ";
      webPage +=    analogRead(36);
      webPage += "</p>";
      webPage += "<p>AnalogPin 39 = ";
      webPage +=    analogRead(39);
      webPage += "</p>";
      webPage += "</body></html>";
      client.println(webPage);
      break;
    }
    // Даём веб-браузеру время для получения данных
    delay(1);
    // Закрываем соединение
    client.stop();
    Serial.println("client disconnected");
  }
}

Открываем монитор порта, узнаём адрес сервера, подключаемся к странице и получаем показания от аналоговых выводов.

Сокет-сервер. Общаемся через Putty

Использовать ESP32 в качестве веб-сервера не всегда удобно и оправданно. Мы можем общаться с микроконтроллером через сокеты.

Начало кода полностью совпадает - мы указываем свой идентификатор и пароль для входа в WiFi-сеть, затем инициализируем объект WiFiServer и пытаемся войти в сеть. В успешном случае мы получим в мониторе порта IP-адрес платы. Его следует запомнить.


#include <WiFi.h>

// Замените на свой идентификатор и пароль
const char* ssid     = "your_ssid";
const char* password = "your_pass";

// Номер порта для сервера
WiFiServer wifiServer(80);

void setup() {
  Serial.begin(115200);

  delay(1000);

  WiFi.begin(ssid, password);

  while (WiFi.status() != WL_CONNECTED) {
    delay(1000);
    Serial.println("Connecting to WiFi..");
  }

  Serial.println("Connected to the WiFi network");
  Serial.println(WiFi.localIP());

  wifiServer.begin();
}

void loop() {
  WiFiClient client = wifiServer.available();

  if (client) {
    while (client.connected()) {
      while (client.available() > 0) {
        char c = client.read();
        Serial.write(c);
      }
      delay(10);
    }

    client.stop();
    Serial.println("Client disconnected");
  }
}

После того как вы запустите код на ESP32, можно подключиться к плате через приложение Putty на компьютере.

Скачайте последнюю версию Putty, я выбираю zip-вариант без установщика.

Запустите приложение, введите IP-адрес, который вы должны увидеть в мониторе порта и установите номер порта для соединения 80.

Putty

После этого откроется чёрное окно терминала, в котором вы можете вводить текст. Команда должна завершаться клавишей Enter.

Putty

В мониторе порта вы будете видеть ваши команды.

ESP32 Serial Monitor
Реклама

Реклама